class ToyGraph extends Graph {
  ToyGraph(int numAgents, int agentSize) {
    super(numAgents, agentSize);
    constructToyStadium();
    registerGraph();
  }
  // ========== Geometry ==========
  void constructToyStadium() {
    //createPolyArc(r,   cx,cy,cz,    n,    a,da,dy,   type)
    //AList stad2top = createPolyArc(400, 400,0,400, 30, 0.0,(3*PI/2),0.0, Corridor);
    AList stad2top = createPolyArc(500, 500,0,500, 30, 0.0,(3*PI/2),0.0, Corridor);
    tiltPolyArc(stad2top,150.0);
    //AList stad2bot = createPolyArc(300, 400,100,400, 30, 0.0,(3*PI/2),0.0, Corridor);
    AList stad2bot = createPolyArc(350, 500,100,500, 30, 0.0,(3*PI/2),0.0, Corridor);
    tiltPolyArc(stad2bot,100.0);
    ArrayList stat2mesh = createMesh(stad2top,stad2bot, 10, Aisle, Row);

    AList stad1top = createPolyArc(600, 600,200,600, 50, 0.0,(3*PI/2),0.0, Corridor);
    //tiltPolyArc(stad1top,150.0);
    tiltPolyArc(stad1top,50f);
    AList stad1bot = createPolyArc(400, 600,300,600, 50, 0.0,(3*PI/2),0.0, Corridor);
    //tiltPolyArc(stad1bot,100.0);
    ArrayList stat1mesh = createMesh(stad1top, stad1bot, 20, Aisle, Row);

    //AList stairs0 = createPolyArc(50, -100,350,400, 50, 3*PI/2,6*PI,-300, Ramp);
    //AList stairs1 = createPolyArc(50, 400,350,-100, 50, 0*PI/2,-6*PI,-300, Ramp);
    AList stairs0 = createPolyArc(50, -50,300,400, 50, 3*PI/2,6*PI,-250, Ramp);
    AList stairs1 = createPolyArc(50, 400,300,-50, 50, 0*PI/2,-6*PI,-250, Ramp);


    //connectClosestPair(stairs0, stad1bot, Ramp);
    connectClosestPair(stairs0, stad1top, Ramp);
    //connectClosestPair(stairs0, stad2bot, Ramp);
    connectClosestNode((Node)stairs0.last(), stad2top, Ramp);
    stairs0.first().setType(Exit);

    //connectClosestPair(stairs1, stad1bot, Ramp);
    connectClosestPair(stairs1, stad1top, Ramp);
    //connectClosestPair(stairs1, stad2bot, Ramp);
    connectClosestNode((Node)stairs1.last(), stad2top, Ramp);
    stairs1.first().setType(Exit);

    // Note: We build a Label by general data manipulators, then call 
    // setLabelByData so that the label variable is set in Base.
    Nodes.setData(Base.Label, "");
    stad1top.setDataByIndex(Base.Label,"L","Top");
    stad1bot.setDataByIndex(Base.Label,"L","Bot");
    for(int i = 0; i<stat1mesh.size(); i++) {
      AList a = (AList)stat1mesh.get(i);
      a.setDataByIndex(Base.Label,"L"+i+"-","");
    }
    stad2top.setDataByIndex(Base.Label,"U","Top");
    stad2bot.setDataByIndex(Base.Label,"U","Bot");
    for(int i = 0; i<stat2mesh.size(); i++) {
      AList a = (AList)stat2mesh.get(i);
      a.setDataByIndex(Base.Label,"U"+i+"-","");
    }
    stairs0.setDataByIndex(Base.Label,"R1","");
    stairs1.setDataByIndex(Base.Label,"R2","");

    Nodes.setLabelByData(Base.Label); // synch data with variable
  }
  AList createPolyArc(int r, int cx, int cy, int cz, int n, float a, float da, float dy, String type) {
    println("createPolyArc: "+r+" "+ cx+" "+ cy+" "+cz+" "+n+" "+a+" "+da+" "+dy+" "+type);
    dy = dy/n;
    da = da/(n-1);
    AList l = new AList();
    for(int i = 0; i<n; i++) {
      float theta = a + i*da;
      float x = (float)cx + r*cos(theta);
      float z = (float)cz - r*sin(theta);
      float y = (float)cy + i*dy;
      Node node = new Node(nodeColor, nodeRadius, nodeShape, "", type); //""+i
      node.moveTo(x,y,z);
      l.add(node);
    }
    connectNodes(l, type);
    return l;
  }
  void tiltPolyArc(AList l, float dy) {
    int sz = l.size();
    int n = (sz-1)/2;
    float decr = dy/n;//(n-1);
    for(int i = 0; i<n; i++) {
      Node n0 = (Node)l.get(i);
      Node n1 = (Node)l.get(sz-1-i);
      n0.y += dy;
      n1.y += dy;
      dy = dy - decr;
    }
  }
  AList connectNodePairs(AList nodes0, AList nodes1, String type) {
    AList l = new AList();
    for(int i = 0; i<nodes0.size(); i++) {
      Node n0 = (Node)nodes0.get(i);
      Node n1 = (Node)nodes1.get(i);
      Edge e = new Edge(n0, n1, edgeColor, "", type);
      l.add(e);
    }
    return l;
  }
  ArrayList createMesh(AList nodes0, AList nodes1, int n, String type1, String type2) {
    ArrayList columnNodes = new ArrayList();
    for(int i = 0; i<nodes0.size(); i++) {
      Node n0 = (Node)nodes0.get(i);
      Node n1 = (Node)nodes1.get(i);
      AList segments = createSegmentsBetween(n0, n1, n, type1);
      columnNodes.add(segments);
      if(i>0)
        connectNodePairs((AList)(columnNodes.get(i-1)), segments, type2);
    }
    return columnNodes;
  }
  AList createSegmentsBetween(Node n0, Node n1, int n, String type) { // return list excludes n0, n1
    AList l = new AList();
    float len = n0.lenTo(n1);
    float delta = len/(n+1);
    for(int i = 0; i<n; i++) {
      Node node = new Node(nodeColor, nodeRadius, nodeShape, "", type); //""+i
      node.moveTo(n0.x, n0.y, n0.z);
      node.moveTowards(n1, delta*(i+1));
      l.add(node);
    }
    //l.add(0, n0);
    //l.add(n1);
    connectNodes(l, type);
    connectNodePair(n0, (Node)firstOf(l), type);
    connectNodePair(n1, (Node)lastOf(l), type);
    return l;
  }
  AList connectNodes(AList nodes, String type) {
    AList l = new AList();
    for(int i = 1; i<nodes.size(); i++) {
      Node n0 = (Node)nodes.get(i-1);
      Node n1 = (Node)nodes.get(i);
      //Edge e = new Edge(n0, n1, edgeColor, ""); //n0.label+"-"+n1.label);
      Edge e = connectNodePair(n0, n1, type);
      l.add(e);
    }
    return l;
  }
  Edge connectNodePair(Node n0, Node n1, String type) {
    Edge e = new Edge(n0, n1, edgeColor, "", type); //n0.label+"-"+n1.label);
    return e;
  }
  Edge connectNodePair(AList nodes0, int i0, AList nodes1, int i1, String type) {
    Node n0 = (Node)nodes0.get(i0);
    Node n1 = (Node)nodes1.get(i1);
    return connectNodePair(n0, n1, type);
  }
  Edge connectClosestPair(AList nodes0, AList nodes1, String type) {
    int i0=0, i1=0;
    float dBest = Float.MAX_VALUE;
    for(int i = 0; i<nodes0.size(); i++) {
      Node n0 = (Node)nodes0.get(i);
      for(int j = 0; j<nodes1.size(); j++) {
        Node n1 = (Node)nodes1.get(j);
        float d = n0.lenTo(n1);
        if(d<dBest) {
          i0=i;
          i1=j;
          dBest = d;
        }
      }
    }
    return connectNodePair(nodes0, i0, nodes1, i1, type);
  }
  Edge connectClosestNode(Node n0, AList nodes1, String type) {
    AList nodes0 = new AList();
    nodes0.add(n0);
    return connectClosestPair(nodes0, nodes1, type);
  }


  // I/O for writing the toy stadium to disk for testing.
  // Bomb format is in Graph so that it can be written out when bombs occur dynamically.

  String nodeString(Object o) {
    Node n = (Node)o;
    return n.id+" "+NF(n.x)+" "+NF(n.y)+" "+NF(n.z); //+" \""+n.label+"\"";
  }
  String edgeString(Object o) {
    Edge e = (Edge)o;
    return e.id+" "+e.n0.id+" "+e.n1.id; //+" \""+e.label+"\"";
  }
  String idString(AList a) {
    String s = "";
    for(int i = 0; i<a.size(); i++)
      s+=(i==0?"":",")+((Base)(a.get(i))).id;
    return s;
  }
  void writeGraph(String fileName) {
    ArrayList a = new ArrayList();

    String s = "Nodes [";
    for(int i = 0; i<Nodes.size(); i++)
      s+=(i==0?"":",")+nodeString(Nodes.get(i));
    a.add(s+"]");

    s = "Edges [";
    for(int i = 0; i<Edges.size(); i++)
      s+=(i==0?"":",")+edgeString(Edges.get(i));
    a.add(s+"]");

    a.add("Rows ["+idString(Rows)+"]");
    a.add("Aisles ["+idString(Aisles)+"]");
    a.add("Corridors ["+idString(Corridors)+"]");
    a.add("Ramps ["+idString(Ramps)+"]");
    a.add("ExitNodes ["+idString(ExitNodes)+"]");
    //a.add("Xxx ["+idString(Xxx)+"]");

    saveStrings(fileName, (String[])a.toArray(new String[a.size()]));
  }


}